アクセス規制チェックスクリプト
(2009.06.27)
掲示板２ちゃんねるのアクセス規制をチェックするスクリプトを作りました。全ホスト規制であれば、書き込めないので気がつきますけれど、絞り込みを行なっている規制では、気がつきませんので、チェックしておこうと思います。ブラウザAWebIIから下記のスクリプトを起動、そこから逆にAWebIIを操作して全部の規制情報を取得、私のドメインだけ抽出してHTMLを生成、AWebIIで表示という寸法です。
2009.06.27
規制情報の記述方法に変更(URLのコメントアウト)があって対応、それと規制種別(日本語)を追加しました。
変数「converter」は文字コード変換ツールへの絶対パスです。
実行結果(例)はこんな感じです。
Results of Kisei.
o 6/26 板別サーバ別規制 _BBS_anichara_\.Goh?sakaFL\d+.vectant.ne.jp
o 6/21 板別サーバ別規制 _BBS_news4vip_Ghyogo\d?FL\d+.vectant.ne.jp
o 6/14 板別サーバ別規制 _BBS_musicjm_w\w+.BN\d+.vectant.ne.jp
o 3/1 再再発 永久規制じゃ _BBS_news4vip_Iaichi\d?FL\d+.vectant.ne.jp
End of List.
/*
$VER: check kisei. 2009/06/27
*/
OPTIONS RESULTS
converter = "projvol:develop/dl_tocode/tocode"
host = ADDRESS()
IF "REXX" = host THEN DO
host = "AWEB.1"
ADDRESS VALUE host
END
ADDRESS 'AWEB.1'
USEPROXY DISABLE
LOAD 'http://qb6.2ch.net/_403/madakana.cgi' RELOAD SAVEAS 'RAM:kisei_madakana.html'
WAIT
IF OPEN(out_results, 'RAM:kisei_results.sjis', WRITE) THEN DO
WRITELN(out_results, '<HTML>')
WRITELN(out_results, '<HEAD>')
WRITELN(out_results, '<TITLE>Results of Kisei</TITLE>')
WRITELN(out_results, '</HEAD>')
WRITELN(out_results, '<BODY>')
WRITELN(out_results, 'Results of Kisei.<BR>')
WRITELN(out_results, '<UL>')
IF OPEN(in_madakana, 'RAM:kisei_madakana.html', READ) THEN DO
url = ''
kindtrail = 0
DO WHILE ~EOF(in_madakana)
linebuff = READLN(in_madakana)
vec = INDEX(linebuff, 'vectant')
http = INDEX(linebuff, 'http://')
IF 0 < http THEN DO
url = SUBSTR(linebuff, http)
spos = INDEX(linebuff, ' ')
datestamp = SUBSTR(linebuff, 2, spos - 1)
END
ELSE IF 0 < INDEX(linebuff, '#######################') THEN DO
kindtrail = 1
END
ELSE IF '#' = LEFT(linebuff, 1) & 1 = kindtrail THEN DO
kindtrail = 0
kisei = SUBSTR(linebuff, 2)
END
ELSE IF 0 = vec THEN DO
END
ELSE IF 0 = INDEX(linebuff, '\') THEN DO
END
ELSE DO
tag = LASTPOS('>', linebuff, vec)
IF 0 < tag THEN DO
linebuff = SUBSTR(linebuff, tag + 1)
END
WRITELN(out_results, '<LI>'datestamp' 'kisei' <A HREF="'url'">'linebuff'</A></LI>')
END
END
CALL CLOSE(in_madakana)
END
WRITELN(out_results, '</UL>')
WRITELN(out_results, 'End of List.<BR>')
WRITELN(out_results, '</BODY>')
WRITELN(out_results, '</HTML>')
CALL CLOSE(out_results)
END
ADDRESS COMMAND converter" -iram:kisei_results.sjis -oram:kisei_results.html -ceuc"
OPEN 'file://localhost/RAM:kisei_results.html' RELOAD
